Programming Taskbook


E-mail:

Пароль:

Регистрация пользователя   Восстановление пароля

 

ЮФУ

Электронный задачник по программированию

©  М. Э. Абрамян (Южный федеральный университет), 1998–2023

 

Решения | PascalABC.NET | Обработка файлов

PrevNext


Выполнение заданий на обработку файлов

Данная страница содержит подробное описание процесса решения типовой задачи на обработку двоичных файлов с числовой информацией, а также примеры решения задач на обработку строковых и текстовых файлов.

Двоичные файлы с числовой информацией: File48

Особенности выполнения заданий на обработку файлов рассмотрим на примере задания File48.

File48°. Даны три файла целых чисел одинакового размера с именами SA, SB, SC и строка SD. Создать новый файл с именем SD, в котором чередовались бы элементы исходных файлов с одним и тем же номером: A1B1C1, A2B2C2, ... .

Создание программы-заготовки и знакомство с заданием

Напомним, что программу-заготовку для решения задания можно создать с помощью модуля PT4Load, используя команду меню «Модули | Создать шаблон программы» среды PascalABC.NET. Эта заготовка будет иметь следующий вид (здесь и далее мы не будем указывать начальную директиву uses PT4):

begin
  Task('File48');
end.

После запуска программы на экране появится окно задачника. На рисунке приведен вариант окна — в режиме с динамической компоновкой:

В первой строке раздела исходных данных указаны имена трех исходных файлов (SA, SB и SC) и одного результирующего (SD). В последующих строках раздела исходных данных показано содержимое исходных файлов. Элементы файлов отображаются бирюзовым цветом, чтобы подчеркнуть их отличие от обычных исходных данных (синего цвета) и комментариев (черного цвета).

В режиме с динамической компоновкой на экране отображаются все элементы двоичных файлов, даже если для этого требуется использовать более одной экранной строки; при этом в начале каждой строки указывается порядковый номер первого элемента файла, приведенного в данной строке (элементы нумеруются от 1).

Следует заметить, что при каждом запуске программы с учебным заданием исходные файлы создаются под новыми именами и заполняются новыми данными, а исходные и результирующие файлы, созданные при предыдущем запуске программы, удаляются с диска.

Вернемся к нашей программе, только что запущенной на выполнение. Так как в ней не указаны операторы ввода-вывода, запуск программы считается ознакомительным, проверка решения не производится, а на экране отображается пример верного решения (в нашем случае это числа, которые должны содержаться в результирующем файле при правильном решении задачи). Пример правильного решения отображается серым цветом.

Ввод исходных данных

Добавим в программу фрагмент, позволяющий ввести имена файлов и связать с этими файлами соответствующие файловые переменные. Поскольку мы собираемся работать с четырьмя файлами одного типа, удобно предусмотреть массив для хранения всех файловых переменных:

begin
  Task('File48');
  var f : array of file of integer;
  SetLength(f, 3);
  for var i := 0 to f.Length -1 do
    Reset(f[i], ReadString)
end.

Мы намеренно ограничились тремя итерациями цикла, оставив непрочитанным имя результирующего файла.

Запуск нового варианта программы уже не будет считаться ознакомительным, поскольку в программе выполняется ввод исходных данных. Так как имя результирующего файла осталось непрочитанным, этот вариант решения будет признан неверным и приведет к сообщению «Введены не все требуемые исходные данные. Количество прочитанных данных: 3 (из 4)».

Изменим программу, заменив в заголовке цикла число 3 на 4, и вновь запустим программу. Теперь все данные, необходимые для выполнения задания, в программу введены. Однако задание не выполнено, поскольку результирующий файл не создан. Начиная с версии 4.15, в этой ситуации выводится сообщение (на светло-синем фоне): «Запуск с правильным вводом данных: все требуемые исходные данные введены, результирующий файл не создан» (в предыдущих версиях сообщение имело вид «Результирующий файл не найден»).

Пример программы, приводящей к ошибке времени выполнения

Изменим программу, заменив второй параметр процедуры SetLength на 4, и вновь запустим программу:

begin
  Task('File48');
  var f : array of file of integer;
  SetLength(f, 4);
  for var i := 0 to f.Length -1 do
    Reset(f[i], ReadString)
end.

Теперь запуск программы приведет к следующему сообщению об ошибке: «Error System.IO.FileNotFoundException. Файл ... не найден», причем на месте многоточия будет указан полный путь к файлу, который требуется создать при выполнении задания. Сообщение, начинающееся со слова «Error», означает, что при работе программы произошла ошибка времени выполнения (runtime error). В программах, разработанных на языке PascalABC.NET, любая ошибка времени выполнения приводит к возбуждению исключения (exception). В тексте сообщения вначале указывается тип возникшего исключения (в данном случае System.IO.FileNotFoundException), а затем — его краткое описание.

Создание пустого результирующего файла

Для того чтобы избежать ошибки времени выполнения, отсутствующий файл результатов следует открыть не процедурой Reset, а процедурой Rewrite, которая и обеспечит создание этого файла. Далее, после завершения работы с файлами, открытыми в программе, их необходимо закрыть процедурой Close. Добавим в программу соответствующие операторы:

begin
  Task('File48');
  var f: array of file of integer;
  SetLength(f, 4);
  for var i := 0 to f.Length - 1 do
    if i < 3 then
      Reset(f[i], ReadString)
    else
      Rewrite(f[i], ReadString);
  { * }
  foreach var e in f do
    e.Close;
end.

Комментарий { * } расположен в том месте программы, в котором можно выполнять операции ввода-вывода для всех четырех файлов: они уже открыты процедурами Reset или Rewrite и еще не закрыты процедурой Close.

Запуск нового варианта программы не приведет к ошибке времени выполнения; более того, результирующий файл будет создан. Однако созданный файл останется пустым, т. е. не содержащим ни одного элемента. Начиная с версии 4.15, в этом случае на информационной панели выводится сообщение (на светло-синем фоне): «Запуск с правильным вводом данных: все требуемые данные введены, результирующий файл является пустым» (в предыдущих версиях в этой ситуации на информационной панели выводилось сообщение «Ошибочное решение», а в строке, которая должна содержать элементы результирующего файла, отображался текст EOF — «конец файла», End Of File).

Таким образом, нам осталось реализовать фрагмент алгоритма, обеспечивающий ввод и вывод файловых данных.

Использование неправильных типов для файловых элементов

Во всех ранее рассмотренных вариантах программы мы не использовали операции ввода-вывода для файлов. Поэтому тип файловых элементов не играл никакой роли: вместо типа file of integer мы могли использовать любой другой файловый тип, например, file of real, и результат выполнения программы был бы тем же самым.

Тип файловых элементов становится принципиально важным, если в программе используются операции ввода-вывода для данного файла. Чтобы продемонстрировать это на примере нашей программы, внесем в нее следующие изменения: в описании массива f файловых переменных тип integer заменим на real, в позицию, помеченную комментарием { * }) добавим следующий фрагмент:

  for var i := 0 to 2 do
    f[3].Write(f[i].Read);

Данный фрагмент обеспечивает считывание одного элемента для каждого из трех исходных файлов и запись этих элементов в результирующий файл (в требуемом порядке). Подчеркнем, что мы неправильно указали типы файлов; тем не менее, компиляция программы пройдет успешно, а после ее запуска не произойдет ошибок времени выполнения.

Результат работы программы будет неожиданным: судя по экранной строке с содержимым результирующего файла, в него будут записаны не три, а шесть элементов, по два начальных элемента из каждого исходного файла. Объясняется это тем, что после связывания файлов с файловыми переменными типа file of real элементами файлов стали считаться вещественные числа (занимающие в памяти по 8 байтов), тогда как «на самом деле», т. е. по условию задания, элементами файлов являются целые числа (занимающие в памяти по 4 байта). Поэтому считывание из файла и последующая запись в файл одного «вещественного элемента» фактически приводит к считыванию и записи блока данных размером 8 байтов, содержащего два последовательных целочисленных элемента исходного файла.

Итак, мы выяснили, что ошибки, связанные с несоответствием типов файлов, не выявляются при компиляции и не всегда приводят к ошибкам времени выполнения. Это следует иметь в виду, и при появлении «странных» результирующих данных начинать поиск ошибки с проверки типов файловых переменных.

Заменив в нашей программе описание real на integer и повторно запустив программу, мы получим все еще неверный, но вполне «понятный» результат: созданный файл будет содержать три элемента, совпадающих с начальными элементами исходных файлов.

Правильное решение, его тестирование и просмотр результатов

Приведем, наконец, верное решение задачи File48:

begin
  Task('File48');
  var f: array of file of integer;
  SetLength(f, 4);
  for var i := 0 to f.Length - 1 do
    if i < 3 then
      Reset(f[i], ReadString)
    else
      Rewrite(f[i], ReadString);
  while not f[0].Eof do
    for var i := 0 to 2 do
      f[3].Write(f[i].Read);
  foreach var e in f do
    e.Close;
end.

От предыдущего варианта данное решение отличается добавлением цикла while not f[0].Eof do, который обеспечивает считывание всех элементов из исходных файлов (напомним, что по условию задания все исходные файлы имеют одинаковый размер) и запись их в результирующий файл в нужном порядке. После запуска этого варианта программы и успешного прохождения 5 тестов мы получим сообщение «Задание выполнено!». Нажав клавишу [F2], мы можем вывести на экран окно результатов, в котором будут перечислены все наши попытки решения задачи:

File48     A24/03 12:15 Ознакомительный запуск.
File48     A24/03 12:16 Введены не все требуемые исходные данные.
File48     A24/03 12:18 Error System.IO.FileNotFoundException.
File48     A24/03 12:20 Запуск с правильным вводом данных.
File48     A24/03 12:22 Ошибочное решение.--2
File48     A24/03 12:24 Задание выполнено!

Строковые и текстовые файлы: File67, Text21

В данном пункте описываются особенности выполнения заданий на обработку строковых файлов (т. е. двоичных типизированных файлов, элементами которых являются строки), а также текстовых файлов, содержащих строки различной длины, оканчивающиеся маркерами конца строки.

Двоичные строковые файлы

В качестве примера задания на строковые файлы рассмотрим задание File67.

File67°. Дан строковый файл, содержащий даты в формате «день/месяц/год», причем под день и месяц отводится по две позиции, а под год — четыре (например, «16/04/2001»). Создать два файла целых чисел, первый из которых содержит значения дней, а второй — значения месяцев для дат из исходного строкового файла (в том же порядке).

Для работы со строковыми файлами в системе PascalABC.NET необходимо использовать файловые переменные типа file of ShortString. Переменные, которые используются для операций ввода-вывода, связанных со строковыми файлами, должны иметь тип ShortString. Напомним, что тип ShortString соответствует «коротким» строкам Паскаля (имеющим длину не более 255 символов), в то время как тип string в языке PascalABC.NET позволяет хранить строки практически неограниченной длины (до 2 гигабайт). Типы ShortString и string являются совместимыми по присваиванию, все стандартные процедуры и функции языка Pascal, связанные с обработкой строк, могут принимать в качестве параметров любой из этих типов.

Сразу приведем правильное решение задачи File67, учитывающее отмеченные выше особенности строковых файлов:

begin
  Task('File67');
  var f: file of ShortString;
  Reset(f, ReadString);
  var f1 := CreateFileInteger(ReadString);
  var f2 := CreateFileInteger(ReadString);
  while not f.Eof do
  begin
    var s: ShortString;
    Read(f, s);
    Write(f1, StrToInt(Copy(s, 1, 2)));
    Write(f2, StrToInt(Copy(s, 4, 2)));
  end;
  f.Close;
  f1.Close;
  f2.Close;
end.

Для преобразования строки, изображающей целое число, в соответствующее числовое значение, была использована функция StrToInt. Следует обратить внимание на использование функции CreateFileInteger вместо процедуры Rewrite. Эта функция позволяет объединить описание файловой переменной и ее связывание с созданным файлом. Для открытия существующего файла можно использовать функцию OpenFileInteger. Имеются также варианты данных функций для создания или открытия двоичных файлов с вещественными элементами: CreateFileReal и OpenFileReal. Однако для работы с файлами типа file of ShortString аналогичные функции не реализованы.

Текстовые файлы

В качестве примера задания на текстовые файлы рассмотрим задание Text21.

Text21°. Дан текстовый файл, содержащий более трех строк. Удалить из него последние три строки.

Поскольку текстовые файлы, в отличие от двоичных, нельзя открыть одновременно на чтение и на запись, для изменения текстового файла необходимо воспользоваться вспомогательным файлом. Во вспомогательный файл записываются необходимые результирующие данные, после чего исходный файл удаляется с диска, а имя вспомогательного файла заменяется на имя исходного. Далее, поскольку строки, содержащиеся в текстовом файле, могут иметь различную длину, для определения числа строк необходимо последовательно считать из файла все его строки. Заметим, что, в отличие от двоичных строковых файлов, для чтения данных из текстовых файлов вполне допустимо использовать переменные типа string.

Приведем решение задачи Text21, учитывающее отмеченные выше особенности текстовых файлов:

begin
  Task('Text21');
  var f1 := OpenRead(ReadString);
  var n := 0;
  while not f1.Eof do
  begin
    var s := f1.ReadString;
    n += 1;
  end;
  Reset(f1);
  var f2 := OpenWrite('$T21$.tmp');
  for var i := 1 to n - 3 do
    f2.Writeln(f1.ReadString);
  Close(f1);
  Close(f2);
  Erase(f1);
  Rename(f2, f1.Name);
end.

Следует обратить внимание на то, что для открытия текстовых файлов для чтения или записи можно использовать функции OpenRead и OpenWrite (имеется также функция OpenAppend для открытия текстового файла для дополнения). Для чтения данных из текстового файла можно использовать набор функций с именами, совпадающими с именами стандартных функций ввода. Кроме того, с помощью свойства Name файловой переменной можно получить имя связанного с ней файла.

Этот вариант решения является неэффективным, поскольку требует двух просмотров исходного файла f1: первый — для определения его размера, который записывается в переменную n, второй — для создания вспомогательного файла f2, содержащего все строки исходного файла, кроме трех последних.

Задание Text21 можно выполнить и за один просмотр исходного файла, если воспользоваться следующим наблюдением: строка должна быть записана во вспомогательный файл, если после нее в исходном файле находятся по крайней мере три строки. Таким образом, записывать очередную строку во вспомогательный файл следует только после считывания из исходного файла трех следующих за ней строк. Благодаря такому упреждающему считыванию необходимость в предварительном определении размера исходного файла отпадает. Для хранения строк, которые уже считаны из исходного файла, но еще не записаны во вспомогательный файл, удобно использовать массив из трех элементов.

Приведем программу, реализующую описанный выше эффективный однопроходный алгоритм решения задания:

begin
  Task('Text21');
  var f1 := OpenRead(ReadString);
  var f2 := OpenWrite('$T21$.tmp');
  var s := new string[3];
  for var i := 0 to 2 do
    s[i] := f1.ReadString;
  var n := 0;
  while not f1.Eof do
  begin
    f2.Writeln(s[n]);
    s[n] := f1.ReadString;
    n := (n + 1) mod 3;
  end;
  Close(f1);
  Close(f2);
  Erase(f1);
  Rename(f2, f1.Name);
end.

PrevNext

 

Рейтинг@Mail.ru

Разработка сайта:
М. Э. Абрамян, В. Н. Брагилевский

Последнее обновление:
01.01.2023